04. Fabric 실시간 분석

이전 포스팅에 이어 가져온 데이터로  KQL 쿼리 세트를 만들어 봅니다. 

2024.03.07 - [Microsoft Fabric/Fabric 실습 5 - 실시간 분석] - 02. Fabric 실시간 분석

 

이전 포스팅에서 구성한 KQL 데이터베이스로 이동합니다. 

 

상단의 "New related item"버튼을 클릭하여 KQL Queryset를 선택합니다. 

 

새 KQL Queryset의 이름을 nyctaxiqs 으로 입력하고 "만들기"를 클릭합니다. 

 

새 KQL Queryset가 만들어지면 샘플 예제가 있는 쿼리 편집기가 표시됩니다. 

 

뉴욕시 노란색 택시의 상위 10개 픽업 위치를 반환하는 쿼리를 작성하고 실행해 봅니다. 

nyctaxitrips
| summarize Count=count() by PULocationID
| top 10 by Count

 

이번에는 Locations 테이블과 lookup함수를 사용하여 상위 10개 픽업 위치의 해당 지역을 조회하는 쿼리를 작성하고 실행해 봅니다. render 함수로 바차트도 표현합니다. 

nyctaxitrips
| lookup (Locations) on $left.PULocationID == $right.LocationID
| summarize Count=count() by Zone
| top 10 by Count
| render columnchart

 

KQL은 변칙을 검색하는 기계 학습 기능을 제공합니다.

 

아래 쿼리는 series_decompose_anomalies()함수를 사용하여 맨해튼 지역의 고객이 낸 팁 금액에 변칙(anomalies)을 찾습니다. 

※ 변칙 검색은 계열 분해를 기반으로 하고 함수는 계열(동적 숫자 배열)이 포함된 식을 입력으로 사용하고 점수가 있는 비정상적인 점을 추출합니다.

nyctaxitrips
| lookup (Locations) on $left.PULocationID==$right.LocationID
| where Borough == "Manhattan"
| make-series s1 = avg(tip_amount) on tpep_pickup_datetime from datetime(2022-06-01) to datetime(2022-06-04) step 1h
| extend anomalies = series_decompose_anomalies(s1)
| render anomalychart with (anomalycolumns=anomalies)

 

빨간색 점 위로 마우스를 가져가서 변칙값을 확인합니다. 

 

series_decompose_forecast 함수를 사용하여 예측 기능을 사용할 수도 있습니다. 

아래 쿼리는 맨해튼 지역에서 충분한 택시가 작동하는지 확인하고 시간당 필요한 택시 수를 예측합니다. 

nyctaxitrips
| lookup (Locations) on $left.PULocationID==$right.LocationID
| where Borough == "Manhattan"
| make-series s1 = count() on tpep_pickup_datetime from datetime(2022-06-01) to datetime(2022-06-08)+3d step 1h by PULocationID
| extend forecast = series_decompose_forecast(s1, 24*3)
| render timechart